Category‐ノート:人物名目録（日本）

はじめに

目標

ウィキペディア日本語版が所蔵する日本の人物記事および人物カテゴリの総目録の作成。
すべての日本人記事を網羅するde:Kategorie:Japanerのようなカテゴリを目指す。

総目録の作成過程で、対応するウィキデータ項目のカテゴリの中心主題 (P301)と主題の中心カテゴリ (P910)の記載を促進。
後に実施予定のBotによる人物記事の一括カテゴリ追加作業の下準備を兼ねる。

WP:OC#EPONYMOUS「人物にちなんで命名されたカテゴリには（中略）人物記事に付与するためのカテゴリは付与しないでください」の遵守を奨励。
その遵守のため、「人物にちなんで命名されたカテゴリ」の第一の受け皿となる。

想定用途

人物記事・カテゴリ数の簡易統計。

PetScan向け大規模人物項目集合。

人物関連のカテゴリ追加・除外を監視可能な共有ウォッチリスト。

作業計画

目標の3.の達成を優先するため、目標の2.を行いつつ、人物カテゴリの追加を進める。

一段落したら、#ウィキデータ点検用クエリ結果から、目標の2.および母語表記 (P1559)の記載を進める。

ある程度、ウィキデータへの記載が済んだら、記載したウィキデータを元に人物記事の当カテゴリへの一括追加のBot作業を依頼する。

進捗

報告 2022年9月下旬現在、上記作業計画の1.人物カテゴリの追加およびウィキデータ項目の記載を進めている段階です。先日、依頼してあった人物カテゴリの追加作業がbotにより実行（作業依頼ログ）され、既に手作業で追加済みだった1,141件に加えて、1,027件の人物カテゴリ（対象リスト）が新たに追加され、2022年9月17日02:55 (UTC) 時点でCategory:日本の人物名を冠したカテゴリ下に収録されていたすべての人物カテゴリ計2,168件の当目録への登録が完了しました。作業手順が前後しましたが、現在、これらの人物カテゴリに対応するウィキデータ項目の記載と確認を、ウィキデータ・クエリとPetScanの助力を得ながら順次進めているところです。人物記事の登録のためのウィキデータ項目の点検作業の開始はまだしばらく先になりそうです。--Doraemonplus（会話） 2022年9月24日 (土) 06:15 (UTC)[返信]

ウィキデータ点検用クエリ

その1（日本国籍（相当）だが、日本語の出生名または母語表記の記載がない人物）

#日本国籍（相当）だが、日本語の出生名または母語表記の記載がない人物を抽出。
#2022年4月29日14時現在、登録数は80,360名。
SELECT DISTINCT ?item ?itemLabel ?sitelink WHERE
{
  ?item wdt:P31 wd:Q5. #ヒト
  { ?item wdt:P27 wd:Q17. } #日本
  UNION
  { ?item wdt:P27 wd:Q188712. } #大日本帝国
  UNION
  { ?item wdt:P27 wd:Q28025. } #琉球王国
  UNION
  { ?item wdt:P27 wd:Q205662. } #江戸幕府
  UNION
  { ?item wdt:P27 wd:Q1154406. } #室町幕府
    MINUS
    {
      {
       ?item wdt:P1477 ?p1477. #出生名
       FILTER((LANG(?p1477)) = "ja")
      }
      UNION
      {
       ?item wdt:P1559 ?p1559. #母語表記
       FILTER((LANG(?p1559)) = "ja")
      }
    }
   ?sitelink schema:about ?item;
             schema:isPartOf <https://ja-two.iwiki.icu/>.
   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

ここをクリックするとウィキデータ・クエリを起動します

その2（読み仮名が記載されているが、日本語の出生名または母語表記の記載がない人物）

#読み仮名が記載されているが、日本語の出生名または母語表記の記載がない人物を抽出。
#2022年4月29日14時現在、登録数は57,544名。
SELECT DISTINCT ?item ?itemLabel ?p1814 ?sitelink WHERE
{
 ?item wdt:P31 wd:Q5.
 ?item wdt:P1814 ?p1814. #読み仮名
  MINUS
  {
    {
     ?item wdt:P1477 ?p1477. #出生名
     FILTER((LANG(?p1477)) = "ja")
    }
    UNION
    {
     ?item wdt:P1559 ?p1559. #母語表記
     FILTER((LANG(?p1559)) = "ja")
    }
  }
 ?sitelink schema:about ?item;
           schema:isPartOf <https://ja-two.iwiki.icu/>.
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

ここをクリックするとウィキデータ・クエリを起動します

いずれも、国籍が日本 (Q17)であるか読み仮名 (P1814)が記載されていることから恐らく日本人であろうと思われるが、当カテゴリの指定要件となっている出生名 (P1477)または母語表記 (P1559)の値が未記載の人物項目を抽出するクエリです。このクエリ結果をもとに条件に合致する人物を見つけ出し、出生名または母語表記の値の記入を促進して、ウィキデータ項目と当カテゴリ双方の登録の充実を目指します。なお、母語表記 (P1559)の指定言語と母語 (P103)の指定言語については、必ずしも一致するとは限りません。事実確認および各プロパティ値の記入に際しては、検証可能な事実およびウィキデータにおける合意事項に従ってください。--Doraemonplus（会話） 2022年4月29日 (金) 05:16 (UTC)[返信]