The torus was produced using POV-Ray v3.6 using the following code:

#include "colors.inc"
#include "shapes.inc"   
#include "textures.inc"
#include "functions.inc"

camera
{
       location <-0.5, 3, -2>
       look_at <0, 0, 0>
}

//Striped textures
#declare bluestripes = texture
       {
               pigment
               { 
                       gradient y
                       colour_map{[0 rgb <0,0,1>][0.15 rgb <1,1,1>]}
               }
               scale 0.07
               finish { ambient 0.3 }
               rotate <0,0,90>
       }
       
#declare redstripes = texture
       {
               pigment
               {
                       gradient z
                       colour_map{[0 rgb <0.8,0,0>][0.25 rgb <1,1,1>]}
               }
               scale 0.07
               finish { ambient 0.3 }
       }
       
#declare blueredstripes = texture
       {        
               pigment
               {
                       gradient z
                       colour_map{[0 rgb <0.8,0,0>][0.25 rgb <1,1,1>]}
               }
               scale 0.07
               finish { ambient 0.3 }   
       }              
       texture
       {
               pigment
               {
                       gradient y
                       colour_map{[0 rgb <0,0,0.8>][0.15 rgb <1,1,1> filter 1]}
               }
               scale 0.07
               finish { ambient 0.3 }
               rotate <0,0,90>  
       }

#declare Blob_threshold=0.0001;

#declare double_torus=isosurface
{
       function        //Smoothed sum of two level surfaces
       {
		f_torus((abs(x)-0.15+abs(abs(x)-0.15))/2,y,z+0.012,0.7,0.28)
       }
       contained_by { box { <-1.5,-0.3,-1.5>, <1.5,0.3,1.5> } }      //Set containing box, default is too small
       max_gradient 15
}

//Red part
object
{        
       double_torus
       clipped_by{plane{-x,-0.15}}
       texture
       {
               redstripes
       }
}

//Blue part
object
{        
       double_torus
       clipped_by{plane{x,-0.15}}
       texture
       {
               bluestripes
       }
}

//Intersection part
object
{        
       double_torus
       clipped_by{plane{x,0.15}}
       clipped_by{plane{-x,0.15}}
       texture
       {
               blueredstripes
       }
}

//Empty background
plane
{
       <0, 1, 0>, -2
       no_image
}                               

light_source { <0, 1.5, -2> color White}

この作品の著作権者である私は、この作品を以下のライセンスで提供します。

このファイルはクリエイティブ・コモンズ 表示-継承 3.0 非移植ライセンスのもとに利用を許諾されています。

あなたは以下の条件に従う場合に限り、自由に

• 共有 – 本作品を複製、頒布、展示、実演できます。
• 再構成 – 二次的著作物を作成できます。

あなたの従うべき条件は以下の通りです。

• 表示 – あなたは適切なクレジットを表示し、ライセンスへのリンクを提供し、変更があったらその旨を示さなければなりません。これらは合理的であればどのような方法で行っても構いませんが、許諾者があなたやあなたの利用行為を支持していると示唆するような方法は除きます。
• 継承 – もしあなたがこの作品をリミックスしたり、改変したり、加工した場合には、あなたはあなたの貢献部分を元の作品とこれと同一または互換性があるライセンスの下に頒布しなければなりません。

https://creativecommons.org/licenses/by-sa/3.0CC BY-SA 3.0 Creative Commons Attribution-Share Alike 3.0 truetrue

この文書は、フリーソフトウェア財団発行のGNUフリー文書利用許諾書 (GNU Free Documentation License) 1.2またはそれ以降のバージョンの規約に基づき、複製や再配布、改変が許可されます。不可変更部分、表紙、背表紙はありません。このライセンスの複製は、GNUフリー文書利用許諾書という章に含まれています。http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

あなたは上記のライセンスから、どれか一つ以上を選択できます。